Мой старт в интернет!

Предлагаю проапдейтить скрипт управления Моего Сервера. Для этого замените содержимое файла W:\mysrv.cmd на следующее:

@echo off & prompt #
set ServerDrive=w
set NeedPause=TRUE_
set AppName=Мой сервер (MySrv)
set AppVer=1.1.0
set AppYear=2011
set ServerDrive=%ServerDrive:~0,1%
set Drive=%CD:~0,1%
call :UpperCase %ServerDrive% ServerDrive
call :UpperCase %Drive% Drive
if %Drive%==%ServerDrive% (
  set RootDir=%CD:~0,0%
) else (
  set RootDir=%CD:~2%)
set Prefix=mysrv-
set UsrDir=%RootDir%\usr
set HomeDir=%RootDir%\home
set TmpDir=%RootDir%\tmp
set BinDir=%UsrDir%\bin
set LocalDir=%UsrDir%\local
set CmdDir=%LocalDir%\%Prefix%cmd
set Action=%1
if "%2"=="" (
  set Module=all.modules
) else (
  set Module=%2)
if "%Action%"=="showdrive" (
  echo %ServerDrive%
  if "%NeedPause%"=="TRUE" echo. & pause
  exit /b )
echo %AppName% v%AppVer% (c) 2010-%AppYear% SVsw & echo.
if "%1"=="" ( echo Использование: %~n0%~x0 команда [модуль] & echo.
            echo %~n0%~x0 reload apache & echo %~n0%~x0 restart mysql 
  if "%NeedPause%"=="TRUE" echo. & pause
  exit /b )
if "%Action%"=="serverdrive" (
  echo Серверный диск %ServerDrive%:
  if "%NeedPause%"=="TRUE" echo. & pause
  exit /b )
if "%Action%"=="createdrive" call :CreateDrive & exit /b
if "%Action%"=="deletedrive" call :DeleteDrive & exit /b
set Drive=%ServerDrive%
%Drive%: & cd \
if not exist %Drive%:%CmdDir%\%Prefix%%Module%.cmd (
  set ERRORMSG=Не найден скрипт управления модуля %Module%
  call :Error & exit /b )
call %Drive%:%CmdDir%\%Prefix%%Module%.cmd
if "%Action%"=="install" (
  if "%NeedPause%"=="TRUE" pause
  exit /b )
if "%Action%"=="uninstall" (
  if "%NeedPause%"=="TRUE" pause
  exit /b)
exit /b

rem [ ]---------------------------------------[ ]
 
:CreateDrive
  if exist "%ServerDrive%":\  (
    set ERRORMSG=Диск %ServerDrive%: уже существует
    call :Error & exit /b )
  %Drive%:%BinDir%\psubst.exe /P %ServerDrive%: %CD%\
  if not exist "%ServerDrive%":\ (
    set ERRORMSG=Диск %ServerDrive%: не создан
    call :Error & exit /b )
  echo.
  echo Диск "%ServerDrive%": ассоциирован с директорией %CD%\
  call :Reboot
  exit /b
 
:DeleteDrive
  if "%Drive%"=="%ServerDrive%" (
    set ERRORMSG=Диск %ServerDrive%: может быть удален только из директории установки
    call :Error & exit /b )
  if not exist %ServerDrive%:\ (
    set ERRORMSG=Диск %ServerDrive%: не найден
    call :Error & exit /b )
  %Drive%:%BinDir%\psubst.exe /DF %ServerDrive%:
  if exist %ServerDrive%:\ (
    set ERRORMSG=Диск %ServerDrive%: не удален
    call :Error & exit /b )
  echo.
  echo Диск %ServerDrive%: удален
  echo После перезагрузки компьютера удалите папку %CD%
  call :Reboot
  exit /b
 
:Reboot
  echo.
  echo Сохраните данные и закройте программы
  echo Компьютер будет перезагружен
  echo.
  pause
  %windir%\system32\shutdown.exe -r -t 0
  exit
 
:Error
  echo.
  echo *ОШИБКА* %ERRORMSG%
  echo.
  if "%NeedPause%"=="TRUE" pause
  exit /b
 
:UpperCase
    setlocal enableextensions enabledelayedexpansion
 
    call :Translate "%~1" "U" "strTempString"
 
    endlocal & set %~2=%strTempString%
    exit /b 0
 
:Translate
    setlocal enableextensions enabledelayedexpansion
 
    set strTempString=%~1
 
    for /f "tokens=2,3" %%i in ('findstr.exe /b /l "# " "%~f0"') do (
        if /i "%~2" equ "L" (
            set strTempString=!strTempString:%%~i=%%~j!
        ) else if /i "%~2" equ "U" (
            set strTempString=!strTempString:%%~j=%%~i!
        )
    )
 
    endlocal & set %~3=%strTempString%
    exit /b 0
 
# A a
# B b
# C c
# D d
# E e
# F f
# G g
# H h
# I i
# J j
# K k
# L l
# M m
# N n
# O o
# P p
# Q q
# R r
# S s
# T t
# U u
# V v
# W w
# X x
# Y y
# Z z

В папке W:\usr\local\mysrv-cmd удалите файлы mysrv-drive.manager.cmd, mysrv-error.msg.cmd, mysrv-reboot.pc.cmd, mysrv-upcase.drive.letter.cmd. Функционал этих скриптов перенесен в mysrv.cmd

Реинсталлировать модули не нужно.

WebMoney

Вы можете оказать посильную помощь на поддержку сайта и развитие проектов переводом средств на кошельки платежной системы WebMoney

Z325624025520
E360373898601
U279044372586
R180028144815

Комментарии

QR

Яндекс.Метрика Рейтинг@Mail.ru