Мой старт в интернет!

Предлагаю пропатчить скрипт управления сервисами MySrv. Для этого откройте текстовым редактором файл W:\usr\local\mysrv-cmd\mysrv-service.manager.cmd, замените его содержимое на следующее:

if "%Action%"=="start" net start %ModuleServiceName% & exit /b
if "%Action%"=="stop" net stop %ModuleServiceName% & exit /b
if "%Action%"=="pause" net pause %ModuleServiceName% & exit /b
if "%Action%"=="continue" net continue %ModuleServiceName% & exit /b
if "%Action%"=="restart" net stop %ModuleServiceName% & net start %ModuleServiceName% & exit /b
if "%Action%"=="reload" net stop %ModuleServiceName% & net start %ModuleServiceName% & exit /b
if "%Action%"=="uninstall" net stop %ModuleServiceName% & %Drive%:%BinDir%\instsrv.exe %ModuleServiceName% REMOVE & exit /b
if not "%Action%"=="install" exit /b
%Drive%:%BinDir%\instsrv.exe %ModuleServiceName% %Drive%:%BinDir%\srvany.exe
set $any=*
set $dir=!
set $app=%ModuleBinFile:\=\\%
if "%ModuleBinFileDirectory%"=="%$dir%" (
  call :extractpath $appdir %ModuleBinFile%
) else (
  set $appdir=%ModuleBinFileDirectory%
)
set $appdir=%$appdir:\=\\%
set $apppar=%ModuleBinFileParameters:\=\\%
if exist %Drive%:%TmpDir%\%ModuleServiceName%.reg del /q %Drive%:%TmpDir%\%ModuleServiceName%.reg
call :createreg
regedit /s %Drive%:%TmpDir%\%ModuleServiceName%.reg
del /q %Drive%:%TmpDir%\%ModuleServiceName%.reg
net start %ModuleServiceName% 
exit /b
:createreg
  echo Windows Registry Editor Version 5.00> %Drive%:%TmpDir%\%ModuleServiceName%.reg
  echo. >> %Drive%:%TmpDir%\%ModuleServiceName%.reg 
  echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\%ModuleServiceName%\Parameters]>> %Drive%:%TmpDir%\%ModuleServiceName%.reg
  echo "Application"="%$app%">> %Drive%:%TmpDir%\%ModuleServiceName%.reg
  if not "%$apppar%"=="%$any%" echo "AppParameters"="%$apppar%">> %Drive%:%TmpDir%\%ModuleServiceName%.reg
  if not "%$appdir%"=="%$any%" echo "AppDirectory"="%$appdir%">> %Drive%:%TmpDir%\%ModuleServiceName%.reg
  exit /b
:extractpath
  set %~1=%~dp2
  exit /b

Если вы используете модуль 3proxy замените содержимое файла W:\usr\local\mysrv-cmd\mysrv-3proxy.cmd на следующее:

set ModuleActive=TRUE
if not "%ModuleActive%"=="TRUE" exit /b
set ModuleServiceName=3proxy
set ModuleBinFile=%Drive%:%LocalDir%\3proxy\bin\3proxy.exe
set ModuleBinFileDirectory=!
set ModuleBinFileParameters=*
call %Drive%:%CmdDir%\%Prefix%service.manager.cmd
exit /b

Реинсталлируйте 3proxy следующей парой команд:

mysrv.cmd uninstall 3proxy
mysrv.cmd install 3proxy

Если вы используете модуль SlimFTPd замените содержимое файла W:\usr\local\mysrv-cmd\mysrv-ftp.cmd на следующее:

set ModuleActive=TRUE
if not "%ModuleActive%"=="TRUE" exit /b
set ModuleServiceName=SlimFTPd
set ModuleBinFile=%Drive%:%LocalDir%\slimftpd\slimftpd.exe
set ModuleBinFileDirectory=!
set ModuleBinFileParameters=*
call %Drive%:%CmdDir%\%Prefix%service.manager.cmd
exit /b

Реинсталлируйте SlimFTPd следующей парой команд:

mysrv.cmd uninstall ftp
mysrv.cmd install ftp

Если вы используете модуль FileZilla FTP Server замените содержимое файла W:\usr\local\mysrv-cmd\mysrv-fzftp.cmd на следующее:

set ModuleActive=TRUE
if not "%ModuleActive%"=="TRUE" exit /b
set ModuleServiceName="FileZilla Server"
set ModuleBinFile="%Drive%:%LocalDir%\FileZilla Server\FileZilla Server.exe"
if "%Action%"=="install" %ModuleBinFile% /install auto & net start %ModuleServiceName% & exit /b
if "%Action%"=="uninstall" net stop %ModuleServiceName% & %ModuleBinFile% /uninstall & exit /b
call %Drive%:%CmdDir%\%Prefix%service.manager.cmd
exit /b

Реинсталляция модуля не нужна.

Если вы используете модуль uTorrent замените содержимое файла W:\usr\local\mysrv-cmd\mysrv-utorrent.cmd на следующее:

set ModuleActive=TRUE
if not "%ModuleActive%"=="TRUE" exit /b
set ModuleServiceName=uTorrent
set ModuleBinFile=C:\PROGRA~1\uTorrent\uTorrent.exe
set ModuleBinFileDirectory=*
set ModuleBinFileParameters=*
call %Drive%:%CmdDir%\%Prefix%service.manager.cmd
exit /b

Реинсталляция модуля не нужна.

Если вы используете модуль Cron замените содержимое файла W:\usr\local\mysrv-cmd\mysrv-cron.cmd на следующее:

set ModuleActive=TRUE
if not "%ModuleActive%"=="TRUE" exit /b
set ModuleServiceName=CRON
set ModuleBinFile=%Drive%:%LocalDir%\cron\crons.exe
set ModuleBinFileDirectory=*
set ModuleBinFileParameters=*
if "%Action%"=="install" %ModuleBinFile% /install & net start %ModuleServiceName% & exit /b
if "%Action%"=="uninstall" net stop %ModuleServiceName% & %ModuleBinFile% /uninstall & exit /b
call %Drive%:%CmdDir%\%Prefix%service.manager.cmd
exit /b

Реинсталляция модуля не нужна.

Замените содержимое файла W:\usr\local\mysrv-cmd\mysrv-mysql.cmd на следующее:

set ModuleActive=TRUE
if not "%ModuleActive%"=="TRUE" exit /b
set ModuleServiceName=MySQL
set addtopath=%Drive%:%LocalDir%\MySQL\bin
set ModuleBinFile=%addtopath%\mysqld.exe
if "%Action%"=="install" ( %Drive%:%BinDir%\pathman.exe /as %addtopath%
  %Drive%:%BinDir%\iniman.exe %Drive%:%LocalDir%\mysql\my.ini mysqld.basedir="%ServerDrive%:/usr/local/mysql" >nul
  %Drive%:%BinDir%\iniman.exe %Drive%:%LocalDir%\mysql\my.ini mysqld.datadir="%ServerDrive%:/usr/local/mysql/data" >nul
  %Drive%:%BinDir%\iniman.exe %Drive%:%LocalDir%\mysql\my.ini mysqld.default-storage-engine="MYISAM" >nul
  %ModuleBinFile% --install %ModuleServiceName% --defaults-file="%Drive%:%LocalDir%\MySQL\my.ini"
  net start %ModuleServiceName% & exit /b )
if "%Action%"=="uninstall" ( net stop %ModuleServiceName% & %ModuleBinFile% --remove %ModuleServiceName%
  %Drive%:%BinDir%\pathman.exe /rs %addtopath%  &  exit /b )
call %Drive%:%CmdDir%\%Prefix%service.manager.cmd
exit /b

Реинсталляция модуля не нужна.

Деинсталлируйте Apache

mysrv.cmd uninstall apache

Деинсталлируйте PHP

mysrv.cmd uninstall php

Содержимое файла W:\usr\local\mysrv-cmd\mysrv-php.cmd замените на следующее:

set ModuleActive=TRUE
if not "%ModuleActive%"=="TRUE" exit /b
set ModuleServiceName=PHP
set ModuleBinFile=%Drive%:%LocalDir%\Php\php-cgi.exe
set ModuleBinFileDirectory=!
set ModuleBinFileParameters=-b 127.0.0.1:9000 -c %Drive%:%LocalDir%\Php\php.ini
set addtopath=%Drive%:%LocalDir%\Php;%Drive%:%LocalDir%\Php\ext
if "%Action%"=="install" %Drive%:%BinDir%\pathman.exe /as %addtopath%
call %Drive%:%CmdDir%\%Prefix%service.manager.cmd
if "%Action%"=="uninstall" %Drive%:%BinDir%\pathman.exe /rs %addtopath%
exit /b

Содержимое файла W:\usr\local\mysrv-cmd\mysrv-apache.cmd замените на следующее:

set ModuleActive=TRUE
if not "%ModuleActive%"=="TRUE" exit /b
set ModuleServiceName=Apache2.2
set addtopath=%Drive%:%LocalDir%\Apache\bin
set ModuleBinFile=%addtopath%\httpd.exe
if "%Action%"=="reload" %ModuleBinFile% -k restart & exit /b
if "%Action%"=="install" %Drive%:%BinDir%\pathman.exe /as %addtopath% & %ModuleBinFile% -k install & net start %ModuleServiceName% & exit /b
if "%Action%"=="uninstall" net stop %ModuleServiceName% & %%ModuleBinFile%% -k uninstall & %Drive%:%BinDir%\pathman.exe /rs %addtopath% & exit /b
call %Drive%:%CmdDir%\%Prefix%service.manager.cmd
exit /b

Инсталлируйте PHP

mysrv.cmd install php

Инсталлируйте Apache

mysrv.cmd install apache
WebMoney

Вы можете оказать посильную помощь на поддержку сайта и развитие проектов переводом средств на кошельки платежной системы WebMoney

Z325624025520
E360373898601
U279044372586
R180028144815

Комментарии

QR

Яндекс.Метрика Рейтинг@Mail.ru